///////// haruka the "Conductor" 〜 「レチハルカ」
///////// 追加イベント辞書
///////// written by hinoharu.



//**** 初期化 *****************************************************************

//**** 通知イベント *********************************************************************

OnNotifySelfInfo
{
	SELFINFO.GhostName   = reference0
	SELFINFO.SakuraName  = reference1
	SELFINFO.KeroName    = reference2
	SELFINFO.ShellName   = reference3
	SELFINFO.ShellPath   = reference4
	SELFINFO.BalloonName = reference5
	SELFINFO.BalloonPath = reference6
}

//**** 変更イベント *********************************************************************

OnBalloonChange
{
	SELFINFO.BalloonName = reference0
	SELFINFO.BalloonPath = reference1
	
//	ANCHOR.InitAnchor // 重い！
}
	

OnShellChanged.SelfInfoUpdate // OnShellChangedの本体は aya_bootend.dic
{
	SELFINFO.ShellName   = reference0
	SELFINFO.ShellPath   = reference2
}

OnShowSelfInfo
{
	SELFINFO.GhostName + '\n'
	--
	SELFINFO.SakuraName + '\n'
	--
	SELFINFO.KeroName + '\n'
	--
	SELFINFO.ShellName + '\n'
	--
	SELFINFO.ShellPath + '\n'
	--
	SELFINFO.BalloonName + '\n'
	--
	SELFINFO.BalloonPath + '\n'
}


//**** キー入力 *****************************************************************
OnKeyPress
{
	if reference0 == "f12"
	{
		OnAiTalk
	}
	elseif reference0 == "f9"
	{
//		Choice_WORDRANDOM
	}
	elseif reference0 == "f8"
	{
//		OnStationquiz_Question
	}
	elseif reference0 == "f7"
	{
		QUESTIONS.Classical
		//OnMENU.AnswerClassicalQuestions
	}
	elseif reference0 == "t"
	{
		OnAiTalk
	}
	elseif reference0 == "n"
	{
		OnAiTalk('n')
	}
	elseif reference0 == "w"
	{
		// 最後のAIトークをもういちど
		TALK.LastTalk
	}
	elseif reference0 == "r"
	{
		'\![reload,shiori]'
		//OnMENU.AnswerClassicalQuestions
	}
	elseif reference0 == "d" // デバッグ出力
	{
		OnMENU.ShowCountOfTalks
	}
	elseif reference0 == "q" // 一時的！
	{
		DATE.SeirekiTest("%year","%month","%day")
	}
}


//**** アンカー選択 *************************************************************
//**** けっこう重要


OnChoiceSelect
{
	_ref = SPLIT(reference0,':',2)
	_tag = _ref[0] // http, dic, その他
	
	// \__q[tag:content]○○\__q の形式を採用
	// tag の内容に応じて、動作を振り分ける
	
	// 使わない（2008.10.22）
}



// AIトーク中のアンカー単語など、バルーンタイムアウトに
// 影響を与えないのはこちら
OnAnchorSelect
{
	// \_a[tag:content]○○\_a の形式を採用
	// tag の内容に応じて、動作を振り分ける
	
	_ref = SPLIT(reference0,':',2)
	_tag = _ref[0] // http, dic, その他
	
	if _tag  == 'http'　// 引数がURLの場合、リンク先をブラウザで開く
	{
		"\j[%(reference0)]"
		return
	}
	elseif _tag == 'dic' // 用語解説のタグ
	{
		ANCHOR.DicAnchorSelected( TOINT(_ref[1]) )
	}
	if _tag == 'dicnavi' // 用語解説の一覧のページナビゲート
	{
		ANCHOR.GetIndexPage( TOINT(_ref[1]) )
	}
	elseif _tag == 'dicnaviret' // 用語解説の一覧に戻るリンク
	{
		LastIndexPage // 保存してあったLastIndexPageをひもとく
	}
	elseif _tag == 'dicnavitalk' // 最後のAIトークに戻るリンク
	{
		TALK.LastTalk// 保存してあった最後のAIトークをひもとく（必ずしもリンクもととは限らない！）
	}
	elseif _tag == 'dicsearchall'
	{
		OnWordSearchShowResultAll( _ref[1] )
	}
	elseif _tag == 'music' // 名曲紹介へのリンク
	{
		MUSIC.SearchTag(_ref[1])
	}
	elseif _tag == 'composerinitial'
	{
		MUSIC.ShowComposerList( _ref[1] )
	}
	elseif _tag == 'composer'
	{
		MUSIC.ShowWorks( _ref[1] )
	}
	elseif _tag == 'work'
	{
		MUSIC.Exp(TOINT(_ref[1]))
	}
	elseif _tag == 'ghostquestions'
	{
		QUESTIONS.Classical.CallIndex( TOSTR(TOINT(_ref[1])) )
	}
	elseif _tag == 'ghostquestionslist'
	{
		QUESTIONS.Classical.Index
	}
	elseif _tag == 'privatequestions'
	{
		QUESTIONS.Private.CallIndex( TOSTR(TOINT(_ref[1])) )
	}
	elseif _tag == 'privatequestionslist'
	{
		QUESTIONS.Private.Index( TOSTR(TOINT(_ref[1])) )
	}
	elseif _tag == 'tonequiz' // 聴音クイズ・解答
	{
		TONE.Clicked(_ref[1])
	}
	elseif _tag == 'tonequizdelete' // 聴音クイズ・削除
	{
		TONE.Deleted(_ref[1])
	}
	elseif _tag == 'sendmessage' // ウェブ拍手メッセージボックスを開く
	{
		WEBCLAP.SendMessageToGhostMaster
	}
	elseif _tag == 'dummy' // バルーンを閉じる
	{
		'\e'
	}
	
	elseif _tag == 'dateselect'
	{
		DATE.SeirekiTest(_ref[1])
	}
}